-- the ipbus bus fabric, address select logic, data multiplexers
--
library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
use work.ngFEC_pack.all;
--use work.ipbus_addr_decode.all;


entity ipbus_fabric is
  generic(
    n_usr_slv				: positive);
  port(
    ipb_clk, rst			: in 	std_logic;
    ipb_in					: in 	ipb_wbus;
    ipb_out					: out ipb_rbus;
    ipb_to_slaves			: out ipb_wbus_array(0 to n_usr_slv-1);
    ipb_from_slaves		: in 	ipb_rbus_array(0 to n_usr_slv-1));

end ipbus_fabric;

architecture rtl of ipbus_fabric is

	signal sel						: integer;
	type mux_rdata_t 				is array(0 to n_usr_slv) of std_logic_vector(31 downto 0);
	signal mux_rdata				: mux_rdata_t;
	signal ored_ack, ored_err	: std_logic_vector(0 to n_usr_slv);
	signal qstrobe					: std_logic;

begin

sel <= ipb_addr_sel(ipb_in.ipb_addr);

	mux_rdata(n_usr_slv) <= (others => '0');
	ored_ack(n_usr_slv) <= '0';
	ored_err(n_usr_slv) <= '0';

	busgen: for i in n_usr_slv-1 downto 0 generate
		signal qual_rdata: std_logic_vector(31 downto 0);
	begin
		ipb_to_slaves(i).ipb_addr 		<= ipb_in.ipb_addr;
		ipb_to_slaves(i).ipb_wdata 	<= ipb_in.ipb_wdata;
		ipb_to_slaves(i).ipb_strobe 	<= ipb_in.ipb_strobe when sel=i else '0';
		ipb_to_slaves(i).ipb_write 	<= ipb_in.ipb_write;

		qual_rdata 		<= ipb_from_slaves(i).ipb_rdata when sel=i else (others => '0');
		mux_rdata(i) 	<= qual_rdata 		or mux_rdata(i+1);
		ored_ack(i) 	<= ored_ack(i+1) 	or ipb_from_slaves(i).ipb_ack;
		ored_err(i) 	<= ored_err(i+1) 	or ipb_from_slaves(i).ipb_err;		

	end generate;

  ipb_out.ipb_rdata 	<= mux_rdata(0);
  ipb_out.ipb_ack 	<= ored_ack(0);
  ipb_out.ipb_err 	<= ored_err(0);
  
end rtl;